🎉 Added mygui PKGBUILD

mygui/PKGBUILD

@@ -0,0 +1,40 @@
+# Maintainer: Edgar <Edgar{at}AnotherFoxGuy.com>
+
+pkgname=mygui
+pkgver=3.4.0
+pkgrel=1
+pkgdesc="A library for creating Graphical User Interfaces for games and 3D applications"
+arch=('i686' 'x86_64')
+url="http://mygui.info/"
+license=('LGPL')
+depends=('ogre' 'libois-dev')
+makedepends=('cmake')
+provides=('mygui')
+source=("https://github.com/MyGUI/mygui/archive/MyGUI${pkgver}.tar.gz")
+sha512sums=('3f560fd9c7e5b514da40e41c7753dc20649f80b763f5ee20afc9627df3be14242ea833eff09eac16b9e88b1c9fbed7c09def0c5068c832e710c247191fb53487')
+
+prepare() {
+  mkdir -p  mygui-MyGUI${pkgver}/build
+}
+
+build() {
+  cd  mygui-MyGUI${pkgver}/build
+
+  # generate CMake Makefile
+  cmake .. \
+  -DCMAKE_INSTALL_PREFIX=/usr \
+  -DMYGUI_BUILD_DEMOS:BOOL=OFF \
+  -DMYGUI_BUILD_DOCS:BOOL=OFF \
+  -DMYGUI_BUILD_TEST_APP:BOOL=OFF \
+  -DMYGUI_BUILD_TOOLS:BOOL=ON \
+  -DMYGUI_BUILD_PLUGINS:BOOL=OFF \
+  -DCMAKE_BUILD_TYPE=Release
+
+  make -j$(nproc)
+}
+
+package() {
+  cd  mygui-MyGUI${pkgver}/build
+
+  make DESTDIR=${pkgdir} install
+}

ogre-1.11/PKGBUILD

@@ -0,0 +1,42 @@
+# Maintainer: Edgar <Edgar{at}AnotherFoxGuy.com>
+pkgname=ogre-1.11
+pkgver=1.11.6
+pkgrel=1
+pkgdesc='Scene-oriented, flexible 3D engine written in C++'
+arch=('x86_64')
+url='https://www.ogre3d.org'
+license=('custom:MIT')
+depends=('libfreeimage-dev' 'libfreetype6-dev' 'libzzip-dev' 'libois-dev'
+         'nvidia-cg-toolkit' 'libzzip-dev' 'libtinyxml-dev' 'libxrandr-dev'
+         'libgles2-mesa-dev' 'libxt-dev' 'libxaw7-dev' 'libglu1-mesa-dev')
+makedepends=('cmake')
+provides=('ogre=1.11')
+source=("https://github.com/OGRECave/ogre/archive/v${pkgver}.tar.gz")
+sha512sums=('a6c3b23d9fb9a01caaa08ae23ab779cb209911957b95736a09ceb67443f0189ec1bed624c35e40f262dd3af0a0491fbcaf652342a28cb320aa654eba1a338d30')
+
+prepare() {
+  mkdir -p ogre-${pkgver}/build
+}
+
+build() {
+  cd ogre-${pkgver}/build
+
+  cmake .. \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DOGRE_BUILD_DEPENDENCIES=FALSE \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DOGRE_BUILD_PLUGIN_FREEIMAGE=TRUE \
+    -DOGRE_BUILD_PLUGIN_EXRCODEC=TRUE \
+    -DOGRE_BUILD_SAMPLES=FALSE \
+    -DOGRE_INSTALL_DOCS=FALSE
+
+  make -j$(nproc)
+}
+
+package() {
+  cd ogre-${pkgver}/build
+
+  make DESTDIR=${pkgdir} install
+
+  install -Dm644 ../Docs/License.md ${pkgdir}/usr/share/licenses/${pkgname}/license
+}